Mini Kabibi Habibi

layout exr_encode_options {
    constant:
        mEXRLayout:      710;
        mEXRArrangement: 711;
        mEXRPixelType:   712;
        mEXRCompression: 713;

        minLayoutDefaultMenuWidth: 150;

        exrLayoutCluster:      '$$$/Format/OpenEXR/Dialog/Encode/ExrLayout/Cluster=File layout';
        exrArrangementCluster: '$$$/Format/OpenEXR/Dialog/Encode/ExrArrangement/Cluster=Image arrangement';
        exrEncodingCluster:    '$$$/Format/OpenEXR/Dialog/Encode/ExrEncoding/Cluster=Image encoding';

        exrDefaultViewLabel:   '$$$/Format/OpenEXR/Dialog/Encode/ExrDefaultView/Label=Default view:';
        exrDefaultPartLabel:   '$$$/Format/OpenEXR/Dialog/Encode/ExrDefaultPart/Label=Default part:';
        exrTileSizeLabel:      '$$$/Format/OpenEXR/Dialog/Encode/ExrTileSize/Label=Tile size:';
        exrPixelTypeLabel:     '$$$/Format/OpenEXR/Dialog/Encode/ExrPixelType/Label=Pixel type:';
        exrCompressionLabel:   '$$$/Format/OpenEXR/Dialog/Encode/ExrCompression/Label=Compression:';

        exrLayoutTip:          '$$$/Format/OpenEXR/Dialog/Encode/ExrLayout/Tip=Select the OpenEXR layout';
        exrDefaultViewTip:     '$$$/Format/OpenEXR/Dialog/Encode/ExrDefaultView/Tip=Select the default view';
        exrDefaultPartTip:     '$$$/Format/OpenEXR/Dialog/Encode/ExrDefaultPart/Tip=Select the default part';
        exrArrangementTip:     '$$$/Format/OpenEXR/Dialog/Encode/ExrArrangement/Tip=Select how the images are arranged';
        exrTileSizeTip:        '$$$/Format/OpenEXR/Dialog/Encode/ExrTileSize/Tip=Select the tile size';
        exrPixelTypeTip:       '$$$/Format/OpenEXR/Dialog/Encode/ExrPixelType/Tip=Select the image pixel number format';
        exrCompressionTip:     '$$$/Format/OpenEXR/Dialog/Encode/ExrCompression/Tip=Choose the image compression';

    interface:
        macintosh: true;
        windows: false <== !macintosh;

    view exr_encode_options_dialog(name: '$$$/Format/OpenEXR/Dialog/Encode/Title=OpenEXR Save Options',
                                   placement: place_column,
                                   horizontal: align_fill,
                                   vertical: align_fill,
                                   margin: gLargeSpace,
                                   isResizable: false) {
        column(horizontal: align_fill,
               spacing: gSpace) {
            TCluster(placement: place_column,
                     horizontal: align_fill,
                     name: exrLayoutCluster,
                     cluster_style: 'clusterLabelBoldInline',
                     frame: true) {
                ZMenuPopup(identifier: @layout_menu,
                           resourceIdentifier: mEXRLayout,
                           horizontal: align_fill,
                           tooltip: exrLayoutTip);
                row(horizontal: align_fill) {
                    column(horizontal: align_fill,
                           spacing: gGap) {
                        TStaticText(identifier: @default_view_label,
                                    horizontal: align_left,
                                    name: exrDefaultViewLabel,
                                    tooltip: exrDefaultViewTip,
                                    wincontrol: false);
                        ZMenuPopup(identifier: @default_view_menu,
                                   uniqueID: true,
                                   width: minLayoutDefaultMenuWidth,
                                   horizontal: align_fill,
                                   tooltip: exrDefaultViewTip);
                    }
                    column(horizontal: align_fill,
                           spacing: gGap) {
                        TStaticText(identifier: @default_part_label,
                                    horizontal: align_left,
                                    name: exrDefaultPartLabel,
                                    tooltip: exrDefaultPartTip,
                                    wincontrol: false);
                        ZMenuPopup(identifier: @default_part_menu,
                                   uniqueID: true,
                                   width: minLayoutDefaultMenuWidth,
                                   horizontal: align_fill,
                                   tooltip: exrDefaultPartTip);
                    }
                }
            }

            TCluster(placement: place_column,
                     horizontal: align_fill,
                     name: exrArrangementCluster,
                     cluster_style: 'clusterLabelBoldInline',
                     frame: true) {
                ZMenuPopup(identifier: @arrangement_menu,
                           resourceIdentifier: mEXRArrangement,
                           horizontal: align_fill,
                           tooltip: exrArrangementTip);
                row(horizontal: align_fill,
                    spacing: gGap) {
                    TStaticText(identifier: @tile_size_label,
                                horizontal: align_left,
                                name: exrTileSizeLabel,
                                tooltip: exrTileSizeTip,
                                isLabel: true,
                                wincontrol: false);
                    ZMenuPopup(identifier: @tile_size_menu,
                               uniqueID: true,
                               horizontal: align_fill,
                               tooltip: exrTileSizeTip);
                }
            }

            TCluster(placement: place_column,
                     horizontal: align_fill,
                     spacing: gGap,
                     name: exrEncodingCluster,
                     cluster_style: 'clusterLabelBoldInline',
                     frame: true) {
                row(horizontal: align_fill,
                    spacing: gGap) {
                    TStaticText(identifier: @pixel_type_label,
                                horizontal: align_left,
                                name: exrPixelTypeLabel,
                                tooltip: exrPixelTypeTip,
                                isLabel: true,
                                wincontrol: false);
                    ZMenuPopup(identifier: @pixel_type_menu,
                               resourceIdentifier: mEXRPixelType,
                               horizontal: align_fill,
                               tooltip: exrPixelTypeTip);
                }
                row(horizontal: align_fill,
                    spacing: gGap) {
                    TStaticText(identifier: @compression_label,
                                horizontal: align_left,
                                name: exrCompressionLabel,
                                tooltip: exrCompressionTip,
                                isLabel: true,
                                wincontrol: false);
                    ZMenuPopup(identifier: @compression_menu,
                               resourceIdentifier: mEXRCompression,
                               horizontal: align_fill,
                               tooltip: exrCompressionTip);
                }
            }
        }

        column(horizontal: align_fill,
               vertical: align_bottom,
               margin: [gMargin, 0, 0, 0]) {
            TOptional(bind: @macintosh,
                      placement: place_row,
                      horizontal: align_right) {
                TButton(name: '$$$/ControlsStrings/Cancel=Cancel',
                        identifier: @cancel,
                        dismiss: true);
                TButton(name: '$$$/ControlsStrings/OK=OK',
                        identifier: @ok,
                        dismiss: true,
                        default: true);
            }

            /* Flip button order for Windows. */
            TOptional(bind: @windows,
                      placement: place_row,
                      horizontal: align_right) {
                TButton(name: '$$$/ControlsStrings/OK=OK',
                        identifier: @ok,
                        dismiss: true,
                        default: true);
                TButton(name: '$$$/ControlsStrings/Cancel=Cancel',
                        identifier: @cancel,
                        dismiss: true);
            }
        }
    }
}