Mini Kabibi Habibi

layout syntheticFillDialog
{
    constant:
        descriptionTextWidth : 230;
        servicePopupWidth : 165;
        bar_button_height: 35;
        bar_button_width:  38;
        text_button_height: bar_button_height - 8;

    interface:
        includeOptions : false;
        discloseOptions : false;
        showSourceTool : false;
        showReferenceImageFlyoutButton : true;
        showServicePickerButton: false;

    view synthetic_fill_dialog(name: '$$$/Dialog/SyntheticFillDialog/Title=Generative Fill',
                               targetIdentifier: 'dscT',
                               defaultIdentifier: 'genB',
                               placement: place_column,
                               margin: 10,
                               spacing: gSpace,
                               isResizable: false)
    {
        column(horizontal: align_fill, spacing: gSmallGap)
        {
            TStaticText(horizontal: align_left, font: static_small_font,
                        name: '$$$/Dialog/SyntheticFillDialog/PromptLabel=Prompt');
            
            synthetic_fill_prompt(identifier: 'dscT', width: descriptionTextWidth, maxChars: 500, lines: 5);

            row(horizontal: align_fill, spacing: gGap )
            {
                TOptional(bind: @showSourceTool, horizontal: align_left, vertical: align_center)
                {
                    synthetic_fill_source_tool_slot(identifier: @sourceToolSlot, horizontal: align_left, vertical: align_center,
                                                    width: 26, height: 26);
                }

                TOptional(bind: @showReferenceImageFlyoutButton, horizontal: align_left, vertical: align_center)
                {
                    TFlyoutIconButton(identifier : @referenceImageFlyoutButton, horizontal: align_left,
                                      vertical: align_center, placement: place_row, spacing: gSmallGap,
                                      flyoutControlId: @grfi,
                                      iconRootName: 'ReferenceImage',   // Sorry, this is ignored - must set in C++ code
                                      tooltip: '$$$/SyntheticFill/ReferenceImage=Edit your reference image.')
                    {
                        TCustomDrawFlyoutControl(identifier: @grfi, vertical: align_center, richtooltip: true,
                                                 width: gToolOptionsIconWidth, height: gToolOptionsIconHeight);
                    }
                }

                TOptional(bind: @showServicePickerButton, horizontal: align_left, vertical: align_center ) 
                {
                    TFlyoutIconButton(identifier : @servicePickerFlyoutButton,
                            horizontal: align_left,
                            vertical: align_center,
                            placement: place_row,
                            iconRootName: 'gen_ai_firefly_icon',
                            spacing: gSmallGap,
                            flyoutControlId: @servicePickerFlyout,
                            tooltip: '$$$/Dialog/SyntheticFillDialog/ServicePicker/Tooltip=Choose a model.')
                    {
                        TCustomDrawFlyoutControl(identifier: @servicePickerFlyout, vertical: align_center,
                                                width: gToolOptionsIconWidth, height: gToolOptionsIconHeight);
                    }
                }

                TStaticText(name: "$$$/ControlsStrings/Cancel=Cancel",
                            identifier: 'hcnl',
                            horizontal: align_right,
                            vertical: align_center,
                            dismiss: true);

                TStaticText(horizontal: align_right,vertical: align_center);

                TIconButton(identifier: 'genB',
                        width: bar_button_width,
                        height: text_button_height,
                        horizontal: align_right,
                        vertical: align_center,
                        dataType: 'int32',
                        frame: 2,
                        fontColorFromTheme: true,
                        alignIconTextTogether: true,
                        iconRootName: 'CxUI_GenFill',
                        name: '$$$/Dialog/SyntheticFillDialog/Generate=Generate',
                        layoverText: '$$$/Dialog/SyntheticFillDialog/Button/Generate/Label=Generate',
                        layoverTextPosition: align_right,
                        tooltip: '$$$/Dialog/SyntheticFillDialog/Button/Generate/ToolTip=Modify existing content, extend images, and generate objects, backgrounds and scenes.');
            }

            TOptional(bind: @includeOptions, horizontal: align_fill)
            {
                TDisclosureSeparator(name: '$$$/Dialog/SyntheticFillDialog/Options=Options', bind: @discloseOptions,
                                     horizontal : align_fill, hasSeparator: false, font: static_small_font);

                TOptional(bind: @discloseOptions, horizontal: align_fill)
                {
                    row(horizontal: align_fill, margin: [0, 5, 0, 5], child_vertical: align_center, spacing: gGap)
                    {
                        TStaticText(name: '$$$/Dialog/SyntheticFillDialog/Service=Service:', horizontal: align_right, font: static_small_font);
                        ZMenuPopup(uniqueID: true, identifier: @servicePopup, horizontal: align_right, width: servicePopupWidth, font: static_small_font);
                    }
                }
            }
        }
    }
}